***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Apr. 15, 2025                                                        *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ1908     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     307.9
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=1.75  VTO=1.18  LEVEL=3  VMAX=5.5e4  ETA=0.003  gamma=0.63)
Rd     d1    d2    995m    TC=6.7m,18u
Dbd     s2    d2    Dbt
.MODEL   Dbt   D(BV=55  TBV1=9.871e-4  CJO=4.633e-12  M=2.180e-1  VJ=1.527e-1)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=9.16e-8  N=1.851  RS=4e-8  EG=0.930  TT=20n IKF=2.369e-2 tikf=1.113e-2)
Rdiode  d1  21    9.626e-2 TC=-1m
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   1.551e-11
.MODEL     DGD    D(cjo=1.551e-11   M=3.833e-1   VJ=1.994e-1)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    1.205e-11
.ENDS PJQ1908
*$
